openhd-git: add OpenHD package

openhd-git/.SRCINFO

@@ -0,0 +1,28 @@
+pkgbase = openhd-git
+	pkgdesc = Open-source digital FPV system
+	pkgver = 2.5.0.beta3.r381.gf559237
+	pkgrel = 1
+	url = https://openhdfpv.org
+	arch = any
+	license = GPL3
+	makedepends = cmake
+	makedepends = git
+	depends = gstreamer
+	depends = gst-plugins-bad
+	depends = gst-plugins-ugly
+	depends = libcamera
+	depends = libpcap
+	depends = libsodium
+	depends = sdl2
+	depends = sudo
+	depends = v4l-utils
+	optdepends = rtl88x2bu-openhd-dkms-git: driver for RTL88x2BU Wi-Fi cards
+	optdepends = rtl8812au-openhd-dkms-git: driver for RTL88xxAU Wi-Fi cards
+	provides = openhd
+	conflicts = openhd
+	source = git+https://github.com/OpenHD/OpenHD.git
+	source = 0001-fix-compile-on-gcc-13.patch
+	sha256sums = SKIP
+	sha256sums = f5353f5411a41833a050cee54d9b461261c8a68eb9051547830960d06c0c0733
+
+pkgname = openhd-git

openhd-git/.gitignore

@@ -0,0 +1,3 @@
+*
+!/PKGBUILD
+!/.SRCINFO

openhd-git/0001-fix-compile-on-gcc-13.patch

@@ -0,0 +1,26 @@
+From f15c889cf40d7c96a01af1e12f443b14c27872ba Mon Sep 17 00:00:00 2001
+From: Rihards Skuja <rihards@skuja.eu>
+Date: Fri, 3 Nov 2023 15:41:01 +0200
+Subject: [PATCH] fix compile on gcc 13
+
+Without the header compilation fails with a bunch of
+"'uint8_t' does not name a type" errors.
+---
+ src/HelperSources/StringHelper.hpp | 1 +
+ 1 file changed, 1 insertion(+)
+
+diff --git a/src/HelperSources/StringHelper.hpp b/src/HelperSources/StringHelper.hpp
+index f00bf9c..1e8e774 100644
+--- a/src/HelperSources/StringHelper.hpp
++++ b/src/HelperSources/StringHelper.hpp
+@@ -9,6 +9,7 @@
+ #include <sstream>
+ #include <array>
+ #include <vector>
++#include <cstdint>
+ 
+ class StringHelper {
+  public:
+-- 
+2.42.1
+

openhd-git/PKGBUILD

@@ -0,0 +1,41 @@
+# Maintainer: Rihards Skuja <rihards at skuja dot eu>
+
+pkgname=openhd-git
+_reponame=OpenHD
+pkgver=2.5.0.beta3.r381.gf559237
+pkgrel=1
+pkgdesc='Open-source digital FPV system'
+arch=(any)
+url='https://openhdfpv.org'
+license=(GPL3)
+depends=(gstreamer gst-plugins-bad gst-plugins-ugly libcamera libpcap libsodium sdl2 sudo v4l-utils)
+makedepends=(cmake git)
+optdepends=(
+	'rtl88x2bu-openhd-dkms-git: driver for RTL88x2BU Wi-Fi cards'
+	'rtl8812au-openhd-dkms-git: driver for RTL88xxAU Wi-Fi cards'
+)
+provides=("${pkgname%-git}")
+conflicts=("${pkgname%-git}")
+source=("git+https://github.com/OpenHD/$_reponame.git" "0001-fix-compile-on-gcc-13.patch")
+sha256sums=('SKIP'
+            'f5353f5411a41833a050cee54d9b461261c8a68eb9051547830960d06c0c0733')
+
+pkgver() {
+	cd "$_reponame"
+	git describe --long --tags --abbrev=7 | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+prepare() {
+	cd "$_reponame"
+	git submodule update --init --recursive
+	patch -d 'OpenHD/lib/wifibroadcast' -p1 -i "$srcdir/0001-fix-compile-on-gcc-13.patch"
+}
+
+build() {
+	cmake -B build -S "$_reponame/OpenHD" -DCMAKE_INSTALL_PREFIX=/usr -Wno-dev
+	cmake --build build
+}
+
+package() {
+	DESTDIR="$pkgdir" cmake --install build
+}