# Maintainer: Rihards Skuja <rihards at skuja dot eu>

pkgname=qopenhd-git
_reponame=QOpenHD
pkgver=2.5.3.r59.g261877c
pkgrel=1
pkgdesc='The default OpenHD companion app'
arch=(any)
url='https://github.com/OpenHD/QOpenHD'
license=(GPL3)
# TODO: add proper dependencies
depends=(qt5-base gstreamer gst-plugins-bad gst-plugins-ugly libcamera libpcap libsodium sdl2 sudo v4l-utils)
makedepends=(git)
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=("git+https://github.com/OpenHD/$_reponame.git" "0001-fix-compile-when-using-the-latest-GCC-and-FFmpeg-ver.patch")
sha256sums=('SKIP'
            'f8371953163197e7255797991285e9fda84733958274b0609cfc1023c5b6d25c')

pkgver() {
	cd "$_reponame"
	git describe --long --tags --abbrev=7 | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
	cd "$_reponame"
	git submodule update --init --recursive
	patch -p1 -i "$srcdir/0001-fix-compile-when-using-the-latest-GCC-and-FFmpeg-ver.patch"
}

build() {
	mkdir -p "$_reponame/build"
	cd "$_reponame/build"
	qmake ..
	make
}

package() {
	install -Dm755 "$_reponame/build/release/QOpenHD" "$pkgdir/usr/bin/QOpenHD"
}